Type-Tiny — Type::Tie

Synopsis

Type::Tie is a response to this sort of problem...

   use strict;
   use warnings;
   
   {
      package Local::Testing;
      use Moose;
      has numbers => ( is => "ro", isa => "ArrayRef[Num]" );
   }
   
   # Nice list of numbers.
   my @N = ( 1, 2, 3, 3.14159 );
   
   # Create an object with a reference to that list.
   my $object = Local::Testing->new(numbers => \@N);
   
   # Everything OK so far...
   
   # Now watch this!
   push @N, "Monkey!";
   print $object->dump;
   
   # Houston, we have a problem!

Just declare @N like this:

   use Type::Tie;
   use Types::Standard qw( Num );
   
   ttie my @N, Num, ( 1, 2, 3, 3.14159 );

Now any attempt to add a non-numeric value to @N will die.

Description

This module exports a single function: ttie . ttie ties a variable to a type constraint, ensuring that whatever values stored in the variable will conform to the type constraint. If the type constraint has coercions, these will be used if necessary to ensure values assigned to the variable conform.

   use Type::Tie;
   use Types::Standard qw( Int Num );
   
   ttie my $count, Int->plus_coercions(Num, 'int $_'), 0;
   
   print tied($count)->type, "\n";   # 'Int'
   
   $count++;            # ok
   $count = 2;          # ok
   $count = 3.14159;    # ok, coerced to 3
   $count = "Monkey!";  # dies

While the examples in documentation (and the test suite) show type constraints from Types::Standard , any type constraint objects supporting the Type::API interfaces should work. This includes:

However, with Type::Tiny, you don't even need to use Type::Tie .

   use Types::Standard qw( Int Num );
   
   tie my $count, Int->plus_coercions(Num, 'int $_'), 0;
   
   print tied($count)->type, "\n";   # 'Int'
   
   $count++;            # ok
   $count = 2;          # ok
   $count = 3.14159;    # ok, coerced to 3
   $count = "Monkey!";  # dies

Cloning tied variables

If you clone tied variables with dclone from Storable , the clone will also be tied. The Clone module is also able to successfully clone tied variables. With other cloning techniques, your level of success may vary.

Type::Tie

Synopsis

Description

Cloning tied variables

See Also